内置渲染管线中的接收阴影着色器示例

实现对接收阴影的支持需要将基本光照传递编译成多个变体，以便正确处理“无阴影的方向光”和“有阴影的方向光”的情况。#pragma multi_compile_fwdbase 指令可以实现这一点（有关详细信息，请参阅多个着色器变体）。实际上，它做了更多的事情：它还为不同的光照贴图预渲染的纹理，其中包含光源对场景中静态对象的影响。光照贴图叠加在场景几何体上以创建照明效果。更多信息
请参阅术语表类型、EnlightenGeomerics 在 Unity 中用于 Enlighten 实时全局照明的照明系统。更多信息
请参阅术语表实时全局照明一组模拟直接和间接照明以提供逼真照明结果的技术。
请参阅术语表开启或关闭等编译变体。目前我们不需要所有这些，因此我们将显式跳过这些变体。

然后，为了获得实际的阴影计算，我们将#include “AutoLight.cginc” 着色器在 GPU 上运行的程序。更多信息
请参阅术语表包含文件并使用其中的 SHADOW_COORDS、TRANSFER_SHADOW、SHADOW_ATTENUATION 宏。

以下是着色器

Shader "Lit/Diffuse With Shadows"
{
    Properties
    {
        [NoScaleOffset] _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader
    {
        Pass
        {
            Tags {"LightMode"="ForwardBase"}
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            // compile shader into multiple variants, with and without shadows
            // (we don't care about any lightmaps yet, so skip these variants)
            #pragma multi_compile_fwdbase nolightmap nodirlightmap nodynlightmap novertexlight
            // shadow helper functions and macros
            #include "AutoLight.cginc"

            struct v2f
            {
                float2 uv : TEXCOORD0;
                SHADOW_COORDS(1) // put shadows data into TEXCOORD1
                fixed3 diff : COLOR0;
                fixed3 ambient : COLOR1;
                float4 pos : SV_POSITION;
            };
            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.uv = v.texcoord;
                half3 worldNormal = UnityObjectToWorldNormal(v.normal);
                half nl = max(0, dot(worldNormal, _WorldSpaceLightPos0.xyz));
                o.diff = nl * _LightColor0.rgb;
                o.ambient = ShadeSH9(half4(worldNormal,1));
                // compute shadows data
                TRANSFER_SHADOW(o)
                return o;
            }

            sampler2D _MainTex;

            fixed4 frag (v2f i) : SV_Target
            {
                fixed4 col = tex2D(_MainTex, i.uv);
                // compute shadow attenuation (1.0 = fully lit, 0.0 = fully shadowed)
                fixed shadow = SHADOW_ATTENUATION(i);
                // darken light's illumination with shadow, keep ambient intact
                fixed3 lighting = i.diff * shadow + i.ambient;
                col.rgb *= lighting;
                return col;
            }
            ENDCG
        }

        // shadow casting support
        UsePass "Legacy Shaders/VertexLit/SHADOWCASTER"
    }
}

看，我们现在有阴影了！