表面着色器中粒子系统 GPU 实例化的示例

这是一个使用粒子系统一个组件，通过在场景中生成和动画化大量的小型 2D 图像来模拟流体实体，例如液体、云和火焰。 更多信息
参见 术语表 GPU 实例化的完整工作示例着色器在 GPU 上运行的程序。 更多信息
参见 术语表。

Shader "Instanced/ParticleMeshesSurface" {
    Properties {
        _Color ("Color", Color) = (1,1,1,1)
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        _Glossiness ("Smoothness", Range(0,1)) = 0.5
        _Metallic ("Metallic", Range(0,1)) = 0.0
    }
    SubShader {
        Tags { "RenderType"="Opaque" }
        LOD 200

        CGPROGRAM
        // Physically based Standard lighting model, and enable shadows on all light types
        // And generate the shadow pass with instancing support
        #pragma surface surf Standard nolightmap nometa noforwardadd keepalpha fullforwardshadows addshadow vertex:vert
        // Enable instancing for this shader
        #pragma multi_compile_instancing
        #pragma instancing_options procedural:vertInstancingSetup
        #pragma exclude_renderers gles
        #include "UnityStandardParticleInstancing.cginc"
        sampler2D _MainTex;
        struct Input {
            float2 uv_MainTex;
            fixed4 vertexColor;
        };
        fixed4 _Color;
        half _Glossiness;
        half _Metallic;
        void vert (inout appdata_full v, out Input o)
        {
            UNITY_INITIALIZE_OUTPUT(Input, o);
            vertInstancingColor(o.vertexColor);
            vertInstancingUVs(v.texcoord, o.uv_MainTex);
        }

        void surf (Input IN, inout SurfaceOutputStandard o) {
            // Albedo comes from a texture tinted by color
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * IN.vertexColor * _Color;
            o.Albedo = c.rgb;
            // Metallic and smoothness come from slider variables
            o.Metallic = _Metallic;
            o.Smoothness = _Glossiness;
            o.Alpha = c.a;
        }
        ENDCG
    }
    FallBack "Diffuse"
}

在上面的示例中，与常规的表面着色器一种简化的方法，用于为内置渲染管线编写着色器。 更多信息
参见 术语表相比，有一些细微的差别，这些差别使其能够与粒子实例化一起工作。

首先，您必须添加以下两行以启用过程化实例化，并指定内置顶点设置函数。此函数位于 UnityStandardParticleInstancing.cginc 中，并加载每个实例（每个粒子）的位置数据。

        #pragma instancing_options procedural:vertInstancingSetup
        #include "UnityStandardParticleInstancing.cginc"

示例中的另一个修改是顶点函数，它有两行额外的代码应用每个实例的属性，具体来说，是粒子颜色和纹理图集动画纹理坐标。

            vertInstancingColor(o.vertexColor);
            vertInstancingUVs(v.texcoord, o.uv_MainTex);